Syntax

[stag]         .struct           [expr]

[mem₀]       element         [expr₀]
[mem₁]       element         [expr₁]
       .                 .                 . 

[mem_n]      .tag stag        [expr_n]
       .                 .                 . 

[mem_N]       element         [expr_N]

[size]          .endstruct

label          .tag             stag

Description

The .struct directive assigns symbolic offsets to the elements of a data structure definition. This allows you to group similar data elements together and let the assembler calculate the element offset. This is similar to a C structure or a Pascal record. The .struct directive does not allocate memory; it merely creates a symbolic template that can be used repeatedly.

The .endstruct directive terminates the structure definition.

The .tag directive gives structure characteristics to a label, simplifying the symbolic representation and providing the ability to define structures that contain other structures. The .tag directive does not allocate memory. The structure tag (stag) of a .tag directive must have been previously defined.

Following are descriptions of the parameters used with the .struct, .endstruct, and .tag directives:

• The stag is the structure's tag. Its value is associated with the beginning of the structure. If no stag is present, the assembler puts the structure members in the global symbol table with the value of their absolute offset from the top of the structure. The stag is optional for .struct, but is required for .tag.
• The expr is an optional expression indicating the beginning offset of the structure. The default starting point for a structure is 0.
• The mem_n/N is an optional label for a member of the structure. This label is absolute and equates to the present offset from the beginning of the structure. A label for a structure member cannot be declared global.
• The element is one of the following descriptors: .byte, .char, .int, .long, .word, .string, .pstring, .float, .field, and .tag. All of these except .tag are typical directives that initialize memory. Following a .struct directive, these directives describe the structure element's size. They do not allocate memory. The .tag directive is a special case because stag must be used (as in the definition of stag).
• The expr_n/N is an optional expression for the number of elements described. This value defaults to 1. A .string element is considered to be one byte in size, and a .field element is one bit.
• The size is an optional label for the total size of the structure.

The following examples show various uses of the .struct, .tag, and .endstruct directives.

Example 1

REAL_REC   .struct                  ; stag
NOM        .int                     ; member1 = 0
DEN        .int                     ; member2 = 1
REAL_LEN   .endstruct               ; real_len = 4
            ADD   ACC, @(REAL + REAL_REC.DEN) ;access structure element
REAL       .usect ".ebss", REAL_LEN           ; allocate mem rec

Example 2

CPLX_REC  .struct
REALI     .tag REAL_REC             ; stag
IMAGI     .tag REAL_REC             ; member1 = 0
CPLX_LEN  .endstruct                ; rec_len = 4
COMPLEX   .tag CPLX_REC             ; assign structure attrib
          ADD  ACC, COMPLEX.REALI   ; access structure
          ADD  ACC, COMPLEX.IMAGI
COMPLEX   .usect ".ebss", CPLX_LEN    ; allocate space

Example 3

               .struct         ; no stag puts mems into
     X         .int            ; global symbol table 
     Y         .int            ;create 3 dim templates
     Z         .int
               .endstruct

Example 4

BIT_REC   .struct                   ; stag
STREAM    .string 64      
BIT7      .field  7                 ; bits1 = 64
BIT9      .field  9                 ; bits2 = 64
BIT10     .field  10                ; bits3 = 65
X_INT     .int                      ; x_int = 67
BIT_LEN   .endstruct                ; length = 68
BITS      .tag   BIT_REC
          ADD    AC, @BITS.BIT7       ; move into acc
          AND    ACC, #007Fh          ; mask off garbage bits
BITS      .usect ".ebss", BIT_REC