/****************************************************************************/
/* 由链接器生成的复制表 - 示例 #1                                */
/*                                                                          */
/* 将 3 个独立的任务加载到目标存储器的 3 个独立区域中。      */
/* 它们都必须在存储器的公共区域（覆盖）中运行。         */
/* 在运行每个任务之前，使用由链接器为每个任务生成的复制表         */
/* 将任务复制到其运行空间中。                                      */
/*                                                                          */
/* 创建了两个由链接器生成的 CRC 表。  一个用于 .task1_scn      */
/* ，另一个用于 UNION。  UNION 表将包含        */
/*  .task1_scn、.task2_scn 和 .task3_scn 的  CRC 记录。                       */
/****************************************************************************/
-c
-x
ex1.obj
task1.obj
task2.obj
task3.obj
check_crc.obj
ref_crc.obj
-o ex1.out
-m ex1.map
-stack    0x1000
-heap     0x800
MEMORY
{
PAGE 0 : RESET(R):    origin = 0x000000, length =  0x00002
         VECTORS(R) : origin = 0x000002, length =  0x003FE
         PROG(R)    : origin = 0x3f0000, length =  0x10000
PAGE 1 : RAM1 (RW)  : origin = 0x000402 , length = 0x003FE
PAGE 1 : RAM2 (RW)  : origin = 0x001000 , length = 0x04000
PAGE 1 : RAM3 (RW)  : origin = 0x3e0000 , length = 0x08000
}
 
SECTIONS
{
   UNION
   {
      .task2_scn: load = RAM3, PAGE = 1, table(_task2_ctbl)
      .task3_scn: load = RAM3, PAGE = 1, table(_task3_ctbl)
      .task1_scn: load = RAM3, PAGE = 1, table(_task1_ctbl), 
                                         crc_table(_task1_crctbl)
   } run = PROG, PAGE = 0, crc_table(_union_crctbl, algorithm=CRC16_ALT)
   vectors  : load = VECTORS, PAGE = 0
   .text    : load = PROG, PAGE = 0
   .data    : load = 440h, PAGE = 1
   .cinit   : > PROG, PAGE = 0
   .ebss    : > RAM3, PAGE = 1
   .econst  : > RAM3, PAGE = 1
   .reset   : > RESET, PAGE = 0
   .stack   : > RAM2, PAGE = 1
   .sysmem  : > RAM2, PAGE = 1
   .esysmem : > RAM3, PAGE = 1
   .ovly     > RAM2, PAGE = 1
}