语法

[stag] .cstruct|.cunion [expr]

[mem₀] element [expr₀]
[mem₁] element [expr₁] 
... 
... 

[mem_n] .tag stag [expr_n]

[mem_N] element [expr_N]

[size] .endstruct|.endunion

label .tag stag

说明

添加了 .cstruct 和 .cunion 指令，以支持在汇编代码和 C 代码之间轻松共享通用数据结构。.cstruct 和 .cunion 指令的使用方法与现有 .struct 和 .union 指令相同，还可确保执行与 C 编译器用于 C 结构体和联合体数据类型的布局匹配的数据布局。

特别是，当这些类型嵌套在复合数据结构中时，.cstruct 和 .cunion 指令会强制执行与 C 编译器所用相同的对齐和填充方式。

.endstruct 指令用于终止结构定义。.endunion 指令用于终止联合体定义。

.tag 指令为 label 提供结构特征，简化符号表示，还可定义包含其他结构的结构。.tag 指令不会分配存储器空间，必须先定义 .tag 指令的结构标签 (stag)。

以下是要与 .struct、.endstruct 和 .tag 指令一同使用的参数的说明：

• stag 是结构体的标签，其值与结构体的开头相关联。如果不存在 stag，汇编器会将结构成员放在全局符号表中，其值是它们距结构体顶部的绝对偏移量。stag 对于 .struct 而言是可选项，但对于 .tag 而言是必备项。
• 元素 是以下描述符之一：.byte、.char、.int、.long、.word、.double、.half、.short、.string、.float 和 .field。除了 .tag 之外的所有上述指令都是用于初始化存储器的典型指令。在 .struct 指令之后，这些指令描述结构元素的大小，不分配存储器空间。.tag 指令是一种特例，因为必须使用 stag（如在 stag 的定义中）。
• expr 是一个可选表达式，指示结构体的开始偏移量。结构体的默认起始点为 0。
• expr_n/N 是表示所描述元素数量的可选表达式，该值默认为 1。.string 元素大小是一个字节，.field 元素大小是一位。
• mem_n/N 是结构成员的可选标签。该标签是绝对值，相当于距结构体开始处的当前偏移量。结构成员的标签不能声明为全局标签。
• size 是表示结构体总大小的可选标签。

示例

此示例演示了以 C 表示、将使用汇编代码访问的结构体。

typedef struct STRUCT1 
; {     int i0;      /* offset 0 */ 
;       short s0;    /* offset 4 */ 
; } struct1;         /* size 8, alignment 4 */ 
;
; typedef struct STRUCT2 
; {     struct1 st1; /* offset 0 */ 
;       short s1;    /* offset 8 */ 
; } struct2;         /* size 12, alignment 4 */ 
; 
; The structure will get the following offsets once the C compiler lays out the structure
; elements according to the C standard rules: 
; 
; offsetof(struct1, i0) = 0 
; offsetof(struct1, s0) = 4 
; sizeof(struct1)       = 8  
; offsetof(struct2, s1) = 0 
; offsetof(struct2, i1) = 8 
; sizeof(struct2)       = 12 
; 
; Attempts to replicate this structure in assembly using the .struct/.union directives will not
; create the correct offsets because the assembler tries to use the most compact arrangement: 
struct1     .struct 
i0          .int                ; bytes 0-3 
s0          .short; bytes 4-5 
struct1len  .endstruct          ; size 6, alignment 4 
struct2     .struct 
st1         .tag struct1        ; bytes 0-5 
s1          .short              ; bytes 6-7 
endstruct2  .endstruct          ; size 8, alignment 4 
        .sect "data1" 
        .word struct1.i0        ; 0 
        .word struct1.s0        ; 4 
        .word struct1len        ; 6 
        .sect "data2" 
        .word struct2.st1       ; 0 
        .word struct2.s1        ; 6 
        .word endstruct2        ; 8 
;
; The .cstruct/.cunion directives calculate offsets in the same manner as the C compiler.The resulting
; assembly structure can be used to access the elements of the C structure.Compare the difference 
; in the offsets of those structures defined via .struct above and the offsets for the C code.
cstruct1    .cstruct 
i0          .int                ; bytes 0-3 
s0          .short; bytes 4-5 
cstruct1len .endstruct          ; size 8, alignment 4 
cstruct2    .cstruct 
st1         .tag cstruct1       ; bytes 0-7 
s1          .short; bytes 8-9 
cendstruct2 .endstruct          ; size 12, alignment 4 
        .sect "data3" 
        .word cstruct1.i0, struct1.i0   ; 0 
        .word cstruct1.s0, struct1.s0   ; 4
        .word cstruct1len, struct1len   ; 8 
        .sect "data4" 
        .word cstruct2.st1, struct2.st1 ; 0 
        .word cstruct2.s1, struct2.s1   ; 8 
        .word cendstruct2, endstruct2   ; 12