语法

[stag] .struct [expr]

[mem₀] element [expr₀]
[mem₁] element [expr₁]
... 

[mem_n] .tag stag [expr_n]
... 

[mem_N] element [expr_N]

[size] .endstruct

label .tag stag

说明

.struct 指令用于为数据结构定义的元素分配符号偏移量。这样便可将类似的数据元素分为一组，并由汇编器计算元素偏移量。这与 C 结构或 Pascal 记录相似。.struct 指令不会分配存储器空间；仅创建一个可重复使用的符号模板。

.endstruct 指令用于终止结构定义。

.tag 指令用于为 label 提供结构特征，简化符号表示，还可定义包含其他结构体的结构。.tag 指令不会分配存储器空间，必须事先定义 .tag 指令的结构标签（stag）。

与 .struct、.endstruct 和 .tag 指令一起使用的参数包括：

• stag 是结构体的标签，其值与结构体的开头相关联。如果不存在 stag，汇编器会将结构体成员置于全局符号表中，其值是它们距结构体顶部的绝对偏移量。stag 对于 .struct 而言是可选项，但对于 .tag 而言是必备项。
• expr 是一个可选表达式，指示结构体的开始偏移量。结构体的默认起始点为 0。
• mem_n/N 是结构体成员的可选标签。该标签是绝对值，相当于距结构体开始处的当前偏移量。结构体成员的标签不能声明为全局标签。
• element（元素）是以下描述符之一：.byte、.char、.int、.long、.word、.double、.half、.short、.string、.float、.field 和 .tag。除了 .tag 之外的所有上述描述符都是用于初始化存储器的典型指令。在 .struct 指令之后，这些指令描述结构体元素的大小，不分配存储器空间。.tag 指令是一个特例，因为必须使用 stag（如在 stag 的定义中）。
• expr_n/N 是表示所描述元素数量的可选表达式，该值默认为 1。.string 元素大小是一个字节，.field 元素大小是一位。
• size 是表示结构体总大小的可选标签。

以下示例展示了 .struct、.tag 和 .endstruct 指令的各种用途。

示例 1

       1                    real_rec  .struct                 ; stag
       2          00000000  nom       .int                    ; member1 = 0
       3          00000004  den       .int                    ; member2 = 1
       4          00000008  real_len  .endstruct              ; real_len = 2
       5                    
       6 00000000 0080016C-           LDW  *+B14(real+real_rec.den), A1
       7                                                      ; access structure
       8                    
       9 00000000                     .bss real, real_len     ; allocate mem rec
      10 

示例 2

      11                    cplx_rec  .struct                 ; stag
      12          00000000  reali     .tag real_rec           ; member1  = 0
      13          00000008  imagi     .tag real_rec           ; member2  = 2
      14          00000010  cplx_len  .endstruct              ; cplx_len = 4
      15                    
      16                    complex   .tag cplx_rec           ; assign structure
      17                                                      ; attribute
      18 00000008                     .bss complex, cplx_len  ; allocate mem rec
      19                    
      20 00000004 0100046C-           LDW  *+B14(complex.imagi.nom), A2 
      21                                                      ; access structure
      22 00000008 0100036C-           LDW  *+B14(complex.reali.den), A2 
      23                                                      ; access structure
      24 0000000c 018C4A78            CMPEQ A2, A3, A3

示例 3

       1                              .struct             ; no stag puts
       2                                                  ; mems into global 
       3                                                  ; symbol table
       4                    
       5          00000000  X         .byte               ; create 3 dim 
       6          00000001  Y         .byte               ; templates
       7          00000002  Z         .byte
       8          00000003            .endstruct 

示例 4

       1                    bit_rec   .struct                 ; stag
       2          00000000  stream    .string 64
       3          00000040  bit7      .field  7               ; bit7 = 64
       4          00000040  bit1      .field  9               ; bit9 = 64
       5          00000042  bit5      .field  10              ; bit5 = 64
       6          00000044  x_int     .byte                   ; x_int = 68
       7          00000045  bit_len   .endstruct              ; length = 72 
       8                    
       9                    bits      .tag bit_rec
      10 00000000                     .bss bits, bit_len
      11                    
      12 00000000 0100106C-           LDW  *+B14(bits.bit7), A2
      13                                                     ; load field
      14 00000004 0109E7A0            AND  0Fh, A2, A2       ; mask off garbage