汇编器支持将操作数用作地址、直接值、间接地址、寄存器、移位寄存器或寄存器列表。以下规则适用于指令的操作数。

• # 前缀 — 操作数是直接值。如果使用 # 符号作为前缀，汇编器会将操作数视为直接值。即使操作数为寄存器也适用；汇编器会将寄存器视为值，而不是使用寄存器的内容。例如：

     Label:  ADD R1, R1, #123
             ; Add 123 (decimal) to the value of R1 and place the result in R1.

• 方括号 — 操作数是间接地址。如果将操作数放在方括号内，汇编器会将操作数视为间接地址；即将操作数的内容作为地址使用。间接地址由基址和偏移组成。基址由寄存器指定并由寄存器中的值构成。偏移可以由寄存器、直接值或移位寄存器指定。此外，偏移可以指定为以下之一：
  • 前索引，其中基址和偏移合并构成地址。若要指定前索引偏移，请将偏移放在右侧结束括号内。
  • 后索引，其中从基址构成地址，然后将基址与偏移合并。若要指定后索引偏移，请将偏移放在右侧括号之外。

  偏移可以加到基址或从基址减去。以下是使用间接地址作为操作数的指令示例：

        A: LDR R1, [R1]
             ; Load from address in R1 into R1.
           LDR R7, [R1, #5]
             ; Form address by adding the value in R1 to 5.Load from address into R7.
           STR R3, [R1, -R2]
             ; Form address by subtracting the value in R2 from the value in R1.Store from R3
             ; to memory at address.
           STR R14, [R1, +R3, LSL #2] 
             ; Form address by adding the value in R3 shifted left by 2 to the value in R1.
             ; Store from R14 to memory at address.
           LDR R1, [R1], #5
             ; Load from address in R1 into R1, then add 5 to the address.
           STR R2, [R1], R5
             ; Store value in R2 in the address in R1, then add the value in R5 to the address.

• ! 后缀 — 写回寄存器。如果使用 ! 符号作为后缀，汇编器会将计算出的地址写回基址寄存器。写回寄存器功能仅与间接寻址模式语法搭配使用。

  以下示例展示的指令使用了写回寄存器后缀：

     LDR R1, [R4, #4]! 
       ; Form address by adding the value in R4 to 4.Load from this address into R1, 
       ; then replace the value in R4 with the address.

• ^ 后缀 — 设置 S 位。如果使用 ^ 符号作为后缀，汇编器会设置 S 位。所产生的操作取决于所执行指令的类型以及 R15 是否在传送列表中。更多信息，请参阅 TMS470R1x 用户指南 中的 LDM 和 STM 指令。

     LDMIA SP, {R4-R11, R15}^
       ; Load registers R4 through R11 and R15 from memory at SP.Load CPSR with SPSR.

• 移位寄存器。如果寄存器符号后跟移位类型，计算的值为寄存器中根据以下所定义类型移位的值：

  LSL LSR ASL ASR ROR RRX

  逻辑左移 逻辑右移 算术左移 算术右移 向右旋转 向右旋转扩展

  移位类型可以后跟寄存器或直接值，其值定义了移位量。以下是使用移位寄存器作为操作数的指令示例：

     B: ADD R1, R4, R5, LSR R2
          ; Logical shift right the value in R5 by the value in R2.Add the value in R5 to R4. 
          ; Place result in R1.
        LDR R1, [R5, R4, LSL #4]
          ; Form address by adding the value in R4 shifted left by 4 to the value in R5. 
          ; Load from address into R1.
        CMP R3, R4, RRX
          ; Compare the value in R3 with the value in R4 rotate right extend.

• 花括号 - 操作数为寄存器列表。如果在寄存器两边加上花括号，汇编器会将操作数视为寄存器列表。您可以用逗号分隔各个寄存器，也可以使用连字符指示寄存器范围。以下是使用寄存器列表的指令示例：

        LDMEA R2, {R1, R3, R6}
          ; Pre-decrement stack load.Load registers R1, R3 and R6 from memory at the address in R2.
        STMFD R12, {R1, R3-R5}
          ; Pre-increment stack store.Store from registers R1 and R3 through R5 to memory at the 
          ; address in R12.